<%@ Language=VBScript %>
<%
'*************************************************************************
' DO NOT MODIFY THIS SCRIPT IF YOU WANT UPDATES TO WORK!
' Function : Display details for a specific product, including all
'          : options.
' Product  : CandyPress Store Frontend
' Version  : 6.2
' Modified : May 2007
' Copyright: Copyright (C) 2010 Cavallo Communications, LLC.
'            See "license.txt" for this product for details regarding
'            licensing, usage, disclaimers, distribution and general
'            copyright requirements. If you don't have a copy of this
'            file, you may request one at http://www.candypress.com
'********************************************************************************************
'   Date							Description
' 12/02/06  Added display of stock level message to related products.
' 10/23/05	Added user exit
' 11/20/05	Corrected problem with price display in getProdRelated();
' 04/05/06	Made option required indicator a language phrase
' 04/18/06  Added branding support
' 09/07/07  Added missing variable errMsg
' 09/12/07  Fixed getStockProd to work correctly with related products
' 05/22/08  Fixed showZeroOptionPrice so that options with zero cost will be hiddenimage
' 06/09/08  Added code to return to last displayed category page and sortorder
' 12/17/08  Added code to support multiple product image display
' 03/31/09	Added UOM display to product price
' 02/07/10  Removed tables, replaced with div - candythemes.com
' 03/10/10  Parens where being displayed when stock status was not diplayed
' 03/10/10  Related products was displaying the stock status for the viewed item
'******************************************************************************************
Option explicit
Response.Buffer = true
%>
<!--#include file="_INCappDBConn_.asp"-->
<!--#include file="_INCconfig_.asp"-->
<!--#include file="_INCappFunctions_.asp"-->
<%
'Product
dim IDProduct
dim Description
dim DescriptionLong
dim Price
dim Details
dim relatedKeys
dim listPrice
dim smallImageURL
dim imageURL
dim Stock
dim SKU
dim fileName
dim noShipCharge
dim reviewAllow
dim handlingFee
dim wholesaleprice
dim msrp
dim map
dim refurbished
dim freight
dim brand
dim estimatedship
dim idUOM
dim minorder

'Options
dim priceToAdd
dim percToAdd

'Work Fields
dim testMode
dim revCount
dim revSum
dim numMandatoryOpt
dim optSize
dim errMsg
dim sortField
dim curPage
dim idCategory
dim userroles

'Database
dim mySQL
dim conntemp
dim rstemp
dim rstemp2
dim rsTemp3
dim cats

'Work
dim idCust
dim idOrder
dim action

'*************************************************************************

selectedLang = Request.form("language")
if len(selectedLang) = 2 then
		session("language") = selectedLang
		Response.cookies("language") = selectedLang
		Response.Cookies("language").expires = dateAdd("d",30,now())
else
		selectedLang= Request.queryString("language")
		if len(selectedLang) = 2 then
				session("language") = selectedLang
				Response.cookies("language") = selectedLang
				Response.Cookies("language").expires = dateAdd("d",30,now())
		end if
end if

'Open Database Connection
call openDb()

'Store Configuration
if loadConfig() = false then
	call errorDB(LangText("ErrConfig",""),"")
end if

'Get/Set Cart/Order Session
idOrder = sessionCart()

'Get/Set Customer Session
idCust  = sessionCust()
if not IsNumeric(idCust) then idCust = session.sessionID

'Get/Set Affilate ID
call getIdAffiliate(validHTML(Request.QueryString("idAff")))

'Get action
action = trim(Request.QueryString("action"))
if len(action) = 0 then
	action = trim(Request.Form("action"))
end if
action = lCase(action)

'Check Product Code
idProduct = trim(request("idProduct")&"")
if not IsNumeric(idProduct) then
	'Check SKU
	sku = trim(request("sku")&"")
	if len(sku) > 0 then
		mySQL = "SELECT idProduct " _
				& "FROM   " & tablePrefix & "products " _
				& "WHERE  sku = '" & validSQL(sku,"A") & "' "
		set rsTemp = openRSexecute(mySQL)
		if not rsTemp.EOF then
			idProduct = rsTemp("idProduct")
		else
			errMsg = LangText("ErrInvProdID","")
			call closeDB()
			Response.redirect "sysMsg.asp?errMsg=" & server.URLEncode(errMsg)
		end if
		call closeRS(rsTemp)
	else
		errMsg = LangText("ErrInvProdID","")
		call closeDB()
		Response.redirect "sysMsg.asp?errMsg=" & server.URLEncode(errMsg)
	end if
end if

'Check if Product is being displayed as a Test
if Instr(lCase(Request.ServerVariables("HTTP_REFERER")),"/sa_prod") = 0 then
	testMode = false
else
	testMode = true
end if

'Get Product Detail
mySQL = "SELECT description,descriptionLong,relatedKeys,price,wholesaleprice,idUOM," _
		& "       listprice,smallImageUrl,imageurl,stock,sku," _
		& "       fileName,noShipCharge,reviewAllow,details, handlingFee, minorder " _
		& "FROM   " & tablePrefix & "products " _
		& "WHERE  idProduct = " & validSQL(idProduct,"I") & " "
if not testMode then
	mySQL = mySQL & "AND active = -1"
end if
set rsTemp = openRSexecute(mySQL)
if rsTemp.eof then
	errMsg = LangText("ErrInvProdID","")
	call closeDB()
	Response.redirect "sysMsg.asp?errMsg=" & server.URLEncode(errMsg)
end if
'Assign product DB fields to local fields
relatedKeys     = trim(rsTemp("relatedKeys")&"")
Price			= rsTemp("price")
idUOM			= rsTemp("idUOM")
listPrice		= rsTemp("listPrice")
smallImageURL	= trim(rsTemp("SmallImageUrl")&"")
imageURL		= trim(rsTemp("imageUrl")&"")
Stock			= rsTemp("stock")
sku			    = trim(rsTemp("sku")&"")
fileName		= trim(rsTemp("fileName")&"")
noShipCharge    = trim(rsTemp("noShipCharge")&"")
reviewAllow	    = trim(rsTemp("reviewAllow")&"")
handlingFee		= rsTemp("handlingFee")
wholesaleprice	= rsTemp("wholesaleprice")
minorder        = rsTemp("minorder")

if len(minorder) = 0 or not IsNumeric(minorder) then
	minorder = 1
end if

'Language for product descriptions
Details		    = trim(langProduct(idProduct,"details",rsTemp("details")))
Description	    = trim(langProduct(idProduct,"description",rsTemp("description")))
DescriptionLong = trim(langProduct(idProduct,"DescriptionLong",rsTemp("DescriptionLong")))
closeRS(rsTemp)

'Build a category keyword string
mySQL = "SELECT a.idProduct, b.categoryDesc " _
		& "FROM " & tablePrefix & "Categories_Products a INNER JOIN " & tablePrefix & "Categories b ON a.idCategory = b.idCategory " _
		& "WHERE (((a.idProduct)= " & validSQL(idProduct,"I") & "));"
set rsTemp = openRSexecute(mySQL)
do while not rsTemp.eof
	cats = cats & trim(rsTemp("categoryDesc")) & ","
	rsTemp.moveNext
loop
if len(cats) > 0 then cats = mid(cats,1,len(cats) - 1)
closeRS(rsTemp)
'Get the return parameters
curPage = Request.Form("curPage")
if len(curPage) = 0 or not IsNumeric(curPage) then
	curPage = 1
end if
sortField = validHTML(Request.Form("sortField"))
if len(sortField) = 0 then
	sortField = pListSortOrder
end if
idCategory = Request.Form("idCategory")
if len(idCategory) = 0 or not IsNumeric(idCategory) then
	idCategory = 1 'All Categories
end if
%>
<!--#include file="../UserMods/_INCprodView_.asp"-->
<!--#include file="_INCimageresize_.asp"-->
<!--#include file="../UserMods/_INCtemplate_.asp"-->
<%

'Close Database Connection
call closeDB()

'*************************************************************************
'Main Shopping Cart Display Area
'*************************************************************************
sub cartMain()
%>
<div id="main-page-wrap">
	<div class="page" id="page-wrap">
<%
' Adjust for displayed currency
listPrice = Exchange(listPrice)
price = Exchange(price)
wholesaleprice = Exchange(wholesaleprice)
if Not IsNull(idCust) then
	userroles = session(storeID & "userroles")
	if (CInt(userroles) and CInt(WHOLESALER))  then
		if price > wholesaleprice then price = wholesaleprice
	end if
end if
'if Request.QueryString("Msg") <> "" Then
'Response.write "<div class=""error"" style=""text-align:center;""><font size=""3"">" & validHTML(Request.QueryString("Msg")) & "</font></div>"
'end if
%>
		<form method="post" action="cart.asp" name="additem" >
<%
		'Classic Layout
		if prodViewLayout = "0" then
%>
			<div class="col-50-p">
<%			call getProdDetail() %>
				<div class="spacing">
<%				call getMisc()
					call getProdReview()
					call getFavorites()
					call getWishlist() %>
				</div>
				<!-- end .spacing -->
			</div>
			<!-- end .col-50-p -->
			<div class="col-50-r">
				<div class="spacing">
<%				call getProdImage()
					call otherImages(idProduct)
					call getProdDisc()
					call getOptionsGroups()
                    Response.write("<br />")
                    call getQtyAndAdd()
					if lCase(SKU) <> "cert" then
						call getProdPricing()
					else
						call getCertPricing()
					end if

					
					call getMandatoryMsg()
					call getFreeShipMsg() %>
				</div>
				<!-- end .spacing -->
			</div>
			<!-- end .col-50-r -->
			<div class="clear"></div>
		</form>
	</div>
	<!-- end #page-wrap -->

	<div id="extra-products-info">
		<div class="related-prod-wrap">
<%		call getProdRelated() %>
		</div>
		<!-- end .related-prod-wrap -->
		<div class="prod-recom-wrap">
<%		if pUseProdView = "-1" then call getProductRecommendations(idProduct) %>
		</div>
		<!-- end .prod-recom-wrap -->
		<div class="clear"></div>
	</div>
	<!-- end #extra-products-info -->
<%
		'Professional layout
		else
%>
			<div class="col-50-p">
<%			call getProdDetail() %>
				<div class="spacing">
<%				if pCatalogOnly = 0 then %>
						<h2 style="margin-bottom: 0;"><%=LangText("GenReadyToOrder","")%></h2>
<%				end if
					call getProdDisc()
					call getOptionsGroups()
					call getMandatoryMsg()
                    
                    call getQtyAndAdd()
					call getProdPricing()
                    
					call getProdStock(idProduct)
					call getFreeShipMsg()
                    call getProdReview()
					call getMisc()
                    call getFavorites()
					call getWishlist()
                    %>
					
				</div>
				<!-- end .spacing -->
			</div>
			<!-- end .col-50-p -->
			<div class="col-50-r">
				<div class="spacing">
<%				call getProdImage()
					call otherImages(idProduct)
					
					 %>
				</div>
				<!-- end .spacing -->
			</div>
			<!-- end .col-50-r -->
			<div class="clear"></div>
		</form>
	</div>
	<!-- end #page-wrap -->

	<div id="extra-products-info">
		<div class="related-prod-wrap">
<%		call getProdRelated()%>
		</div>
		<!-- end .related-prod-wrap -->
		<div class="prod-recom-wrap">
<%		if pUseProdView = "-1" then 
				call getProductRecommendations(idProduct)
			end if %>
		</div>
		<!-- end .prod-recom-wrap -->
		<div class="clear">&nbsp;</div>
	</div>
	<!-- end #extra-products-info -->
<%
		end if %>
</div>

<!-- end #main-page-wrap -->

<%
end sub
'*************************************************************************
' Display Product Details
'*************************************************************************
sub getProdDetail()
%>
<div class="spacing">
<h1><%=Description%></h1>
<%
	if len(Details) = 0 then %>
		<%call getProdStock(idProduct)%><%=DescriptionLong%>
<%	else %>
		<%call getProdStock(idProduct)%><%=Details%>
<%	end if
%>
</div>
<%
end sub
'*************************************************************************
' Display Product Pricing
'*************************************************************************
sub getProdPricing()

	'Check if we need to hide pricing if price=0
	if pHidePricingZero=-1 and Price=0 then
		exit sub
	end if

	'Show Prices
%>
	<div class="price">
<%
if lCase(sku) = "cert" then
		'do nothing
	Else

	if listPrice > Price then
%>
	<span class="CPprodLPriceT"><%=LangText("GenListPrice","")%> : </span><del class="CPprodLPriceV"><%=moneyS(ListPrice)%></del><br/>
<%	end if %>

	<%=LangText("GenOurPrice","")%> : <%=moneyS(Price)%>
	
<%	if (listPrice - Price) > 0 then %>
		<br /><span class="CPprodSPriceT"><%=LangText("GenYouSave","")%> : </span> <span class="CPprodSPriceV"><%=moneyS(ListPrice-Price)%> (<%=formatNumber((((listPrice-Price)/listPrice)*100),0)%>%)</span>
<%	end if
	if handlingFee > 0 then
%>
	<br /><br /><span class="CPprodPriceT">+ <%=LangText("GenHandlingFee","")%> : </span> <span class="CPprodSPriceV"><%=moneyS(Exchange(handlingFee))%></span>
<%
	end if
    end if
%>
</div>

<%
end sub

'*************************************************************************
' Display Certificate Pricing
'*************************************************************************
sub getCertPricing()

	'Place a page break here to adjust the spacing as we don't need to
	'show the products price.
	response.write "<br>"

end sub

'*************************************************************************
' Display Product Stock Description
'*************************************************************************
sub getProdStock(idProduct)
		dim rsTemp, mySQL

		mySQL = "SELECT stock FROM " & tablePrefix & "products WHERE idproduct = " & validSQL(idProduct,"I")
		set rsTemp = openRSexecute(mySQL)
		if not rsTemp.eof then
			if pShowStockView = -1 then
				response.write "<span class=""CPstockLevel"">( "
				if pHideAddStockLevel = -1 then %>
					<%=LangText("GenInStock","")%>
		<%		else
					if rsTemp("stock") > pHideAddStockLevel then %>
						<%=LangText("GenInStock","")%>
		<%			else %>
					 <%=LangText("GenOutStock","")%>
		<%			end if
				end if
				response.write " )</span>"
			end if
	end if
end sub
'*************************************************************************
' Display Free Shipping message
'*************************************************************************
sub getFreeShipMsg()
	if UCase(noShipCharge) = "Y" and len(fileName) = 0 then %>
		<div style="clear:both; margin-top:15px;"><br /><strong><%=LangText("GenFreeShipping","")%></strong></div>
<%	end if
end sub
'*************************************************************************
' Produce a selection box for the price of the gift certificate
'*************************************************************************
sub certAmount()
	dim mySQL, rsTemp, i

%>
	<br /><select name="certprice" onChange="if( this.selectedIndex > 0) { document.additem.certprice.value  = this[this.selectedIndex].value } else { document.additem.certprice.value = <%=Exchange(pMinCert)%> }" >
	<option value="<%=Exchange(pMinCert)%>"><%=LangText("CertAmount","Amount")%></option>
<%
	for i = pMinCert to pMaxCert Step pIncrCert
	price = Exchange(i)
%>
		<option value="<%=price%>" ><%=moneyS(price)%></option>
<%
	next
%>
	</select>
<%
end sub

'*************************************************************************
' Display Product Options
'*************************************************************************
sub getOptionsGroups()

	dim mySQL, rstemp, rstemp2, rstemp3, optionDesc

	if lCase(sku) = "cert" then
		call certAmount
	end  if

	'Initialise mandatory option counter
	numMandatoryOpt = 0

	'Get option groups for this Product
	mySQL = "SELECT a.idOptionGroup, a.optionGroupDesc, " _
			& "       a.optionReq, a.optionType, a.optionLength " _
				& "FROM   " & tablePrefix & "optionsGroups a, " & tablePrefix & "optionsGroupsXref b " _
				& "WHERE  a.idOptionGroup = b.idOptionGroup " _
				& "AND    b.idProduct = " & validSQL(idProduct,"I") & " " _
				& "ORDER BY a.sortOrder, a.optionGroupDesc "
	set rsTemp2 = openRSexecute(mySQL)

	'Extra line break before displaying option groups
	if not rsTemp2.EOF then
		Response.Write "<br />"
	end if

	'Loop through option groups
	do while not rstemp2.EOF

		'Get Options for Option Group
		mySQL = "SELECT b.idOption, b.optionDescrip, b.priceToAdd, " _
				& "       b.percToAdd " _
					& "FROM   " & tablePrefix & "optionsXref a, " & tablePrefix & "options b " _
					& "WHERE  a.idOptionGroup = " & rstemp2("idOptionGroup") & " " _
					& "AND    b.idOption = a.idOption " _
					& "AND    NOT EXISTS " _
					& "      (SELECT c.idOptionsProdEx " _
					& "       FROM   " & tablePrefix & "OptionsProdEx c " _
					& "       WHERE  c.idOption = b.idOption " _
					& "       AND    c.idProduct = " & validSQL(idProduct,"I") & ") " _
					& "ORDER BY b.sortOrder, b.optionDescrip "
		set rsTemp3 = openRSexecute(mySQL)
		if not rstemp3.EOF then

			'Show option headings
			if UCase(rstemp2("optionReq")) = "Y" then
				numMandatoryOpt = numMandatoryOpt + 1%>
				<span class="CPoptDescM"><%=LangText(rstemp2("optionGroupDesc"),rstemp2("optionGroupDesc"))%> <%=LangText("GenRequired","(Required)")%> :</span><br />
<%			else %>
				<span class="CPoptDesc"><%=LangText(rstemp2("optionGroupDesc"),rstemp2("optionGroupDesc"))%> :</span><br />
<%			end if

			'Create hidden variables that will be used in validations %>
			<input type="hidden" name='DESidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp2("optionGroupDesc")%>' />
			<input type="hidden" name='REQidOption<%=rstemp2("idOptionGroup")%>' id='REQidOption<%=rstemp2("idOptionGroup")%>'  value='<%=uCase(rstemp2("optionReq"))%>' />
			<input type="hidden" name='TYPidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp2("optionType")%>' />
<%
			'Show Drop-Down List options
			if rstemp2("optionType") = "S" then
				if UCase(rstemp2("optionReq")) = "Y" and OptionInventory(idProduct) then %>
					<select name='OPTidOption<%=rstemp2("idOptionGroup")%>' class="CPoptSel" onChange="getOptionsInventory(<%=idProduct%>,this.form)">
			<% else %>
					<select name='OPTidOption<%=rstemp2("idOptionGroup")%>' class="CPoptSel" >
			<% end if %>
						<option value=""></option>
<%				do while not rstemp3.EOF
					priceToAdd = Exchange(getOptionPrice(rstemp3("priceToAdd"),rstemp3("percToAdd"),price))
					optionDesc = LangText(rstemp3("optionDescrip"),rstemp3("optionDescrip"))
					if priceToAdd > 0 then
						optionDesc = optionDesc & " "
					end if
%>
					<option value='<%=rstemp3("idOption")%>'><%=optionDesc%>
					<% if priceToAdd > 0 then %>
						&nbsp;<%=moneyS(priceToAdd)%>
					<% else
							if showZeroOptionPrice <> "-1" then %>
								&nbsp;
					 <% end if
						end if %>
					</option>
<%					rstemp3.movenext
				loop %>
				</select><br />
<%			end if

			'Show Radio Button options
			if rstemp2("optionType") = "R" then
				'Only show "Not Applicable" if the option group is optional
				if UCase(rstemp2("optionReq")) = "N" then %>
					<nobr>&nbsp;&nbsp;<input type="radio" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value="" checked=""  />
					<span class="CPoptRadio"><%=LangText("GenNotApplicable","")%></span></nobr><br />
<%				end if
				do while not rstemp3.EOF
					priceToAdd = Exchange(getOptionPrice(rstemp3("priceToAdd"),rstemp3("percToAdd"),price))
					optionDesc = rstemp3("optionDescrip")
					if priceToAdd > 0 then
						optionDesc = optionDesc & " "
					 end if
					 if OptionInventory(idProduct) then
%>
						<nobr>&nbsp;&nbsp;<input type="radio" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp3("idOption")%>' onClick="getOptionsInventory(<%=idProduct%>,this.form)"/>
				<%	else %>
						<nobr>&nbsp;&nbsp;<input type="radio" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp3("idOption")%>' />
				<% 	end if %>
					<span class="CPoptRadio"><%=optionDesc%> (<%=moneyS(priceToAdd)%>)</span></nobr><br />
<%					rstemp3.movenext
				loop %>
				<br />
<%			end if

			'Show Checkbox options
			if rstemp2("optionType") = "C" then
				do while not rstemp3.EOF
					priceToAdd = Exchange(getOptionPrice(rstemp3("priceToAdd"),rstemp3("percToAdd"),price))
					optionDesc = rstemp3("optionDescrip")
					if priceToAdd > 0 then
						optionDesc = optionDesc & " "
					 end if
					 if OptionInventory(idProduct) then
%>
						<nobr>&nbsp;&nbsp;<input type="checkbox" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp3("idOption")%>' onClick="getOptionsInventory(<%=idProduct%>,this.form)"/>
				<%	else %>
						<nobr>&nbsp;&nbsp;<input type="checkbox" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp3("idOption")%>' />
				<% 	end if %>
					<span class="CPoptRadio"><%=optionDesc%> (<%=moneyS(priceToAdd)%>)</span></nobr><br />
<%					rstemp3.movenext
				loop %>
				<br />
<%			end if

			'Show Text Input options
			if rstemp2("optionType") = "T" then
				if rsTemp2("optionLength") > 25 then
					optSize = 25
				else
					optSize = rsTemp2("optionLength")
				end if %>
				<input type="hidden" name='OPTidOption<%=rstemp2("idOptionGroup")%>' value='<%=rstemp3("idOption")%>' />
                <% if rstemp2("idOptionGroup") = 5 then %>
				<textarea rows="2" cols="20" id="TXTidOption<%=rstemp2("idOptionGroup")%>" name='TXTidOption<%=rstemp2("idOptionGroup")%>' class="CPoptTxt"></textarea><br />
                <% else %>
				<input type="text" id="TXTidOption<%=rstemp2("idOptionGroup")%>" name='TXTidOption<%=rstemp2("idOptionGroup")%>' size="<%=optSize%>" maxlength='<%=rsTemp2("optionLength")%>' class="CPoptTxt" /><br />
                <% end if %>
<%			

end if

		end if
		call closeRS(rsTemp3)
		rstemp2.movenext
	loop
	call closeRS(rsTemp2)
	if numMandatoryOpt > 0  and OptionInventory(idProduct) then
%>
	<br/><b class="CPinStock"><span id="showInventoryMsg"><%=LangText("GenSelectOptions","Select options to view item stock.")%></span>

	<br /><%=LangText("ItemsInStock","Number available: ")%><span id="showInventory">0</span></b>
<%
	end if
end sub
'*************************************************************************
' Display Qty box and Add Button
'*************************************************************************
sub getQtyAndAdd()
	if pCatalogOnly = 0 and _
		(pHideAddStockLevel = -1 or _
		 pHideAddStockLevel < CDbl(Stock)) then
%>
		<div id="showAdd" >

			<input type="hidden" name="action" value="additem" />
			<input type="hidden" name="idProduct" value="<%=IDProduct%>" />
			<input type="hidden" name="curPage" value="<%=curPage %>" />
			<input type="hidden" name="sortField" value="<%=sortField %>" />
			<input type="hidden" name="idCategory" value="<%=idCategory %>" />
			<input type="hidden" name="certprice" value="" />
            <select name="quantity" class="quantityselect"><option value="1">1</option><option value="2">2</option><option value="3">3</option><option value="4">4</option><option value="5">5</option><option value="6">6</option><option value="7">7</option><option value="8">8</option><option value="9">9</option></select>
			 &nbsp;
						<input type="submit"  name="add" class="awesome large" value="Buy" />

			<%
			if minorder > 1 then response.write "<p>"& LangText("MinQuantityOrder","Product requires a minimum order of ") & minorder &"</p>"
			%>

		</div>
        
<%
	end if
end sub
'*************************************************************************
' Display Product Discounts
'*************************************************************************
sub getProdDisc()

	dim mySQL, rstemp

	'Get Product Discounts
	mySQL="SELECT discAmt,discFromQty,discToQty,discPerc " _
		& "FROM   " & tablePrefix & "DiscProd " _
		& "WHERE  idProduct = " & validSQL(idProduct,"I") & " " _
		& "ORDER BY discFromQty"
	set rsTemp = openRSexecute(mySQL)
	if not rsTemp.EOF then %>
		<h2><%=LangText("GenDiscount","")%> (<%=LangText("GenQty","")%>) :</h2>
		<table border="0" cellpadding="0" cellspacing="0" id="discount-table">
<%		do while not rsTemp.EOF %>
			<tbody>
			<tr>
				<td nowrap=""><%=rsTemp("discFromQty")%></td>
				<td nowrap="">&nbsp;-&nbsp;</td>
				<td nowrap="">
<%					if rsTemp("discToQty") > 9999 then
						Response.Write "&gt;"
					else
						Response.Write rsTemp("discToQty")
					end if %>
				</td>
				<td nowrap="">&nbsp;&nbsp;&nbsp;</td>
				<td nowrap=""><%=LangText("GenSave","")%>&nbsp;
<%				if isNull(rsTemp("discPerc")) then

%>
					<%=moneyS(Exchange(rsTemp("discAmt")))%>
<%					Response.write " " & LangText("GenEach","")
				else
					Response.Write rsTemp("discPerc") & "% " & LangText("GenEach","")
				end if %>
				</td>
			</tr>
<%			rsTemp.Movenext
		loop
%>
		</tbody>
		</table>
<%	end if
	call closeRS(rsTemp)
end sub
'*************************************************************************
' Display Related Products
'*************************************************************************
sub getProdRelated()
	dim mySQL, rstemp, rsTemp2
	dim count
	dim price

	const bullet = "<li>"
%><div id="related-prod">
	<div style="padding-bottom: 25px;"><h2><%=LangText("GenRelatedProd","")%> :</h2></div>

<%
	'Get Product Group products
	mySQL="SELECT prodGroupP " _
		& "FROM   " & tablePrefix & "productGroups " _
		& "WHERE  prodGroupC  = " & validSQL(idProduct,"I")
	set rsTemp = openRSexecute(mySQL)
	do while not rsTemp.EOF
		mySQL="SELECT b.idProduct, b.description,b.price, " _
			& "       b.smallImageURL, b.descriptionLong  " _
			& "FROM   " & tablePrefix & "productGroups a, " & tablePrefix & "products b " _
			& "WHERE  a.prodGroupP = " & rsTemp("prodGroupP") & " " _
			& "AND    a.prodGroupC <> " & validSQL(idProduct,"I") & " " _
			& "AND    b.idProduct  = a.prodGroupC " _
			& "AND    b.active = -1 " _
			& "ORDER BY b.description "
		set rsTemp2 = openRSexecute(mySQL)
		do while not rstemp2.EOF
			price = Exchange(rsTemp2("price"))
			count = count + 1

            %>
							<div class="prod-front-wrap">
                 <div class="prod-front">
					<a class="RecommendationLink" href='prodView.asp?idProduct=<%=rsTemp2("idProduct") %>'>
					<img   class="relatedimage" border="0" src="<%= pImagesDir & rsTemp2("smallImageURL") %>" <%=ImageResize(server.mappath(pImagesDir & smallImageURL),pWThumb,pHThumb,"thumb")%> /></a>
					<br> <h2><%=rsTemp2("description") %></h2>

					<div style="text-align:left;"><%=rsTemp2("DescriptionLong") %></div>
				</div>

				<!-- end .recom-prod-info -->
				<div class="clear"></div>
				</div>
                <%
			rsTemp2.Movenext
		loop
		call closeRS(rsTemp2)
		rsTemp.Movenext
	loop
	call closeRS(rsTemp)
%>
<div style="clear:both;"></div>
</div>
<!-- end #related-prod -->

<div class="spacing">
<%
	'Get categories for this product
	mySQL="SELECT a.idCategory, b.categoryDesc " _
		& "FROM   " & tablePrefix & "Categories_Products a " _
		& "INNER  JOIN " & tablePrefix & "Categories b " _
		& "ON     a.idCategory = b.idCategory " _
		& "WHERE  a.idProduct = " & validSQL(idProduct,"I")
	set rsTemp = openRSexecute(mySQL)
	do while not rsTemp.eof %>
		<!--<a href='prodList.asp?idCategory=<%=rsTemp("idCategory")%>'><%=getCategoryPos(rsTemp("idCategory"),"","Y")%></a>-->
<%		rsTemp.movenext
	loop
	call closeRS(rsTemp)

	'Related keys for this product
	if len(relatedKeys) > 0 then %>
		<!--<a href="prodList.asp?strSearch=<%=server.URLEncode(relatedKeys)%>"><%=LangText("GenSearchRelated","")%></a>-->

<%	end if
%>
</div>
<!-- end .spacing -->
<%
end sub
'*************************************************************************
' Display Product Review Summary
'*************************************************************************
sub getProdReview()

	dim mySQL, rstemp

	'Check if reviews are allowed for this product
	if UCase(reviewAllow) = "Y" then
%>
		<br /><h3><%=LangText("GenProductReviews","")%> :</h3>
<%
		'Get current ratings
		mySQL="SELECT SUM(revRating)   AS revSum,  " _
			& "       COUNT(revRating) AS revCount " _
			& "FROM   " & tablePrefix & "reviews " _
			& "WHERE  idProduct = " & validSQL(idProduct,"I") & " " _
			& "AND    revStatus = 'A' "
		set rsTemp = openRSexecute(mySQL)
		if not rsTemp.EOF then
			revSum   = rsTemp("revSum")
			revCount = rsTemp("revCount")
		else
			revSum   = 0
			revCount = 0
		end if
		call closeRS(rsTemp)

		'Show Ratings
		if revSum > 0 and revCount > 0 then
%>
			<%=LangText("GenAverageRating","")%> : <%=ratingImage(revSum/revCount)%><br />
			<a href="prodReview.asp?idProduct=<%=idProduct%>"><%=LangText("GenNumberReviews","")%></a> : <%=revCount%><br />
<%
		end if
%>
		<a href="prodReview.asp?idProduct=<%=idProduct%>"><%=LangText("GenWriteReview","")%></a><br />
<%
	end if
end sub
'*************************************************************************
' Display Product Image
'*************************************************************************
sub getProdImage()
	if imageURL <> "" then %>
		<img src="<%=pImagesDir & imageURL%>" id="product-detail"  alt="<%=server.HTMLEncode(description)%>"  />
<%	else
		if smallImageURL <> "" then
%>
			<img src="<%=pImagesDir & smallImageURL%>" id="product-detail" alt="<%=server.HTMLEncode(description)%>"  />
<%
		else
%>
			<%=LangText("GenNoImage","")%>
<%
		end if
	end if

end sub
'*************************************************************************
' Get other images
'*************************************************************************
sub otherimages(idProduct)
	dim mySQL
	dim rs
%>
<%
	mySQL = "SELECT smallimageurl, imageurl, title, sort " _
				& "FROM " & tablePrefix & "prodImages " _
				& "WHERE idProduct = " & idProduct & " " _
				& "ORDER BY [sort] "
	set rs = openRSexecute(mySQL)
	if not rs.eof then
%>
<!-- <h3><%=langText("genAdditionalImages","Additional Images: ")%></h3>-->
<%
	end if
	do while NOT rs.eof
%>
		<img src="<%=pImagesDir & rs("smallImageURL")%>" alt="<%=rs("title")%>" border="0" />&nbsp;
<%
		rs.movenext
	loop
%>
	<br />
<%
end sub
'*************************************************************************
' Display Miscellaneous items
'*************************************************************************
sub getMisc()
	if mailComp <> 0 or demoMode = "Y" then
		if pEmailFriend = "-1" or pProdInquiry = "-1" then
%>
		<div style="clear:both; "><br /><h2><%=LangText("GenMiscellaneous","")%> :</h2></div>
		<% if pEmailFriend = "-1" then %>
				<a href="emailToFriend.asp?idProduct=<%=IDProduct%>"><%=LangText("GenEmailFriendHdr","")%></a><br  />
		<% end if
			 if pProdInquiry = "-1" then %>
					<a href='contactUs.asp?emailSubject=<%=server.URLEncode(LangText("GenProdInquiry","") & " : " & SKU & " - " & Description)%>'><%=LangText("GenProdInquiry","")%></a><br />
<%		   end if
		end if
	end if
end sub

'*************************************************************************
' Display "Favorites"
'*************************************************************************
sub getFavorites
	if FavoritesEnabled = "-1" then
%>
	<a href="<%=urlNonSSL%>addFav.asp?ProductId=<%=idProduct%>&amp;action=additem&amp;msg"><%=LangText("GenAddFav","Add to Favorites")%></a><br />
<%
	end if
end sub

'*************************************************************************
' Display "Wish List"
'*************************************************************************
sub getWishList
	if WishlistEnabled = "-1" then
%>
	<a href="wishlist.asp?ProductId=<%=idProduct%>&amp;action=additem"><%=LangText("GenAddWishlist","Add to Wish List")%></a>
<%
	end if
end sub

'*************************************************************************
' Display "Mandatory" message
'*************************************************************************
sub getMandatoryMsg()
	if numMandatoryOpt > 0 then
%>
		<!--<br /><span class="CPoptDescM">(*) <%=LangText("GenMandatoryOpt","")%></span><br />-->
<%
	end if
end sub


'*******************************************************************************
' Display product recommendations based upon a given product
'*******************************************************************************
sub getProductRecommendations(idProduct)
	dim smallImageURL
'	response.write "getProductRecommendations(" & idProduct & ")<br/>"
	mySQL = "SELECT " & tablePrefix & "products.idProduct, sku, description, descriptionLong, imageURL, smallImageURL, idCategory " _
            & "FROM " & tablePrefix & "categories_products INNER JOIN " & tablePrefix & "products ON " & tablePrefix & "categories_products.idProduct = " & tablePrefix & "products.idProduct " _
			& "WHERE active = -1 AND " & tablePrefix & "products.idProduct IN " _
			& "(SELECT TOP " & prodViewRecommendationsCount & " idProduct FROM " & tablePrefix & "cartrows WHERE idOrder IN " _
			& "        (SELECT idOrder FROM " & tablePrefix & "cartrows WHERE idProduct = " & idproduct & ") " _
			& "AND idProduct <> " & idProduct & " " _
			& "GROUP BY idProduct " _
			& "ORDER BY COUNT(idProduct) DESC )"
	'response.write mySQL & "<br/>"
		set rsTemp = openRSexecute(mySQL)
		if not rsTemp.eof then
%>
<div id="recom-prod">
	<div class="alsopurchased"><h2 ><%=LangText("genRecommendProducts","People that purchase this product also purchased : ") %></h2></div>

<%
			do while not rsTemp.eof
			' Display the recommended products
			smallImageURL = rsTemp("smallImageURL")
			imageURL = rsTemp("imageURL")
			if len(smallImageURL) = 0 then
				if len(imageURL) <> 0 then
					smallImageURL = imageURL
				end if
			end if
			if len(smallImageURL) > 0 then
%>

				<div class="prod-front-wrap">
                 <div class="prod-front">
					<a class="RecommendationLink" href='prodView.asp?idProduct=<%=rsTemp("idProduct") %>'>
					<img  ID="relatedimage" cssclass="relatedimage" border="0" src="<%= pImagesDir & rsTemp("smallImageURL") %>" <%=ImageResize(server.mappath(pImagesDir & smallImageURL),pWThumb,pHThumb,"thumb")%> /></a>
					<br> <h2><%=rsTemp("description") %></h2>

					<div style="text-align:left;"><%=rsTemp("DescriptionLong") %></div>
				</div>
<!--                <div id="addbutton">
                <form method="post" id="buy-form" action="cart.asp" name="additem" >

			<input type="hidden" name="action" value="additem" />
			<input type="hidden" name="idProduct" value="<%=rsTemp("idProduct") %>" />
			<input type="hidden" name="curPage" value="1" />
			<input type="hidden" name="sortField" value="sortorder" />
			<input type="hidden" name="idCategory" value="<%=rsTemp("idCategory") %>" />
			<input type="submit" name="add" class="awesome large" value="Buy" />
		</form>
</div>-->
				<!-- end .recom-prod-info -->
				<div class="clear"></div>
				</div>
				<!-- end .recom-prod-detail -->
<%
		end if
		rsTemp.movenext
		loop
%>
</div>
<!-- end #recom-prod -->
<%
	end if

end sub

function OptionInventory(idProduct)
	dim mySQL, rsTemp

	OptionInventory = false
	mySQL = "SELECT inventory FROM " & tablePrefix & "optionsInventory WHERE idproduct = " & validSQL(idProduct,"I") & ";"
	'response.write mySQL
	set rsTemp = openRSexecute(mySQL)
	if not rsTemp.eof then
		OptionInventory = true
	end if
	closeRS(rsTemp)
end function
%>